BEGIN {
	hnb = 0;
	hctrx = "";
	hctry = "";
	hctrk = "";
	snb = 0;
	sctrx = "";
	sctry = "";
	sctrk = "";
	sctrw = "";
	nbvar = 0;
	dom = "";
	nbcat = 0;
	cat = "";
	min_freq = 100000;
	max_freq = 0;
}

match(FILENAME,"cst.txt") && /^ *a[0-9] *= *[0-9]+ *$/ {
	gsub(" ","");
	sub("a","");
	sub("="," ");
	a[$1] = $2;
}

match(FILENAME,"dom.txt") {
	nbcat++;
	idcat[$1] = nbcat;
	cat = cat ",{" $3;
	if ($3>max_freq) max_freq=$3;
	if ($3<min_freq) min_freq=$3;
	for(i=4;i<=NF;i++) {
		cat = cat "," $i;
		if ($i>max_freq) max_freq=$i;
		if ($i<min_freq) min_freq=$i;
	}
	cat = cat "}";
}

match(FILENAME,"var.txt") {
	nbvar++;
	idvar[$1] = nbvar;
	dom = dom "," idcat[$2]
}

match(FILENAME,"ctr.txt") && $4=="=" {
	hnb++;
    hctrx= hctrx "," idvar[$1];
	hctry= hctry "," idvar[$2];
	hctrk = hctrk "," $5;
}

match(FILENAME,"ctr.txt") && $4==">" {
	snb++;
    sctrx= sctrx "," idvar[$1];
	sctry= sctry "," idvar[$2];
	sctrk = sctrk "," $5;
	sctrw = sctrw "," $6;
}

END {
	print "costs= [" a[1] "," a[2] "," a[3] "," a[4] "];";
	print "num_categories= " nbcat ";";
	print "categories= [" substr(cat,2)  "];";
	print "min_freq= " min_freq ";";
	print "max_freq= " max_freq ";";
	print "num_variables= " nbvar ";";
	print "domains= ["  substr(dom,2) "];";
	print "num_hardconstraints= " hnb ";";
	print "hardctrx= [" substr(hctrx,2) "];";
	print "hardctry= [" substr(hctry,2) "];";
	print "hardctrk= [" substr(hctrk,2) "];";
	print "num_softconstraints= " snb ";";
	print "softctrx= [" substr(sctrx,2) "];";
	print "softctry= [" substr(sctry,2) "];";
	print "softctrk= [" substr(sctrk,2) "];";
	print "softctrw= [" substr(sctrw,2) "];";
}